***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Dec 20, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt ES1006FL A K
.param
+vc0 = 4.246e-9		 vc1 = 4.253e-11	 vc2 = 1.000e-0		
+vc3 = 3.341e-10	 vc4 = 6.955e-3
+tc1 = 1.051e-1		 tc2 = 2.291e-2		 tc3 = 6.951e-2		tc4 = 2.921e-2
+tc5 = 1.391e-2		 tc6 = 3.721e-2
.func ir0(v) {(vc0)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
.func ir1(v) {(vc1*v^vc2)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.func ir2(v) {(vc3*exp(vc4*v))*(1.0+tc5*(temp-25)*exp(tc6*(temp-25)))}
.func irexp(v) {ir0(v)+ir1(v)+ir2(v)}
g1 K A value = {irexp(v(K,A))}
d1 A K sbd
.model sbd d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 8.845e-10	   n = 1.428		  rs = 2.453e-1		ikf = 5.240e-3
+ibv = 0.1e-3		 nbv = 1	  	  bv = 660
***** capacitance parameter *****
+cjo = 2.120e-11  	   m = 3.681e-1		  vj = 3.643e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.086e-0		 xti = 3
+trs1 = -6.871e-3	trs2 = 2.004e-5		tikf = 1.236e-2
.ends ES1006FL
*$
